[WotLK] [德鲁伊] 小德各种自用宏分享

五区-异想天开-雲極玖歌
以前分享过，不过现在用的宏之后我又修改过几次，现在重新发下保存
自用宏分享-以下宏仅个人习惯设置按键，复制粘贴请酌情自修，我没有使用自动变身宏，因为宏字数限制255

变身宏-X键(ctrl+X为枭兽形态，植物人请修改为树人形态即可，或者熊猫人修改为巨熊形态)
/cast [nomod,flyable,outdoors]福星木蛟
/cast [nomod,outdoors]迅捷祖利安猛虎
/cast [mod:ctrl]!枭兽形态;[mod:shift/alt,nostealth]!猎豹形态;[swimming]!水栖形态;[indoors]!猎豹形态;[flyable,nocombat]!迅捷飞行形态;!旅行形态
/cast [mod:shift]急奔;[mod:alt]潜行
不在移动时，默认骑上坐骑(可以飞的地图用飞行坐骑,否则地面坐骑，名称需要自行修改)，在水中水栖形态，室内猎豹形态(副本中直接按就行，但是部分可以上坐骑的地图需要搭配组合键变猫)，户外优先飞行形态，否则旅行变豹子
按住组合键ctrl+x为枭兽形态，
shift/alt组合都为猎豹形态，shift+X变猫并开启急奔，适合被冰冻或缠绕下使用解除控制，
alt+X变猫并潜行

打断冲锋整合宏-F键
#showtooltip
/target [@mouseover,harm,nodead]
/cast [mod:shift]自然之握;[mod:ctrl]战争践踏;[mod:alt]!巨熊形态;[nomod,form:1]野性冲锋 - 熊;[nomod,form:3]野性冲锋 - 豹;[nomod,noform:1/3]旋风
/cast [nomod,form:1]猛击;[nomod,form:3,nostealth]潜行
按住组合键shift+F为自然之握，ctrl+F为战争践踏(联盟德自行修改其他技能)
按ALT+F键是无论什么形态都变熊，
熊或者猫形态下默认按键，距离远的时候用野性冲锋，熊形态下距离较近需要多次点击发动猛击，猫形态下为潜行方便冲锋后使用突袭
不在熊/猫形态下使用旋风(不习惯的自行修改)
此宏写了鼠标指向目标发动方便熊猫形态下直接对目标发动冲锋和猛击(缺点：反应慢的人容易选错目标，不习惯的把/target [@mouseover,harm,nodead]这段删除)

驱散控制整合宏-G键
#showtooltip
/stopcasting [help]
/cast [help,dead,nocombat]起死回生;[help,dead,combat]复生;[mod,@mouseover,help,exists,nodead][mod:alt,@player]解除诅咒;[mod:shift]安抚动物;[mod:ctrl]休眠;[@mouseover,help,exists,nodead]驱毒术;[harm,exists,nodead]纠缠根须;驱毒术
非战斗中选中友方已死亡目标为起死回生，战斗中选中友方已死亡目标为复生
目标为友方或者无目标情况下使用驱毒术，目标为敌对目标时使用纠缠根须
组合键ALT+G为解除诅咒，shift+G为安抚动物，ctrl+G为休眠

HOT整合宏-~键(键盘左上数字1键左边那个键就是~键)
#showtooltip
/stopcasting
/cast [mod,noform:1/3,@mouseover,help,exists,nodead]野性成长;[mod,harm,exists,nodead]月火术;[noform:1/3,@mouseover,help,exists,nodead][noform:1/3,help,exists,nodead]生命绽放;[form:1/3]精灵之火(野性);精灵之火
/startattack [harm,nodead,nostealth]
默认情况下使用精灵之火，熊猫形态下为精灵之火(野性)
目标为敌对目标时，组合键使用对敌对目标使用月火术(mod组合键为shift/ctrl/alt，按个人习惯，我自己习惯alt+~键)
目标为友方目标时，默认为生命绽放，组合键使用为野性成长(非植物人可以将野性成长这段宏删除，我自己是玩了2个小德四系都玩)

以下宏不在解释如何使用，为自用组合宏，酌情复制
个人习惯全形态宏
Q键
#showtooltip
/targetenemy [noharm][noexists][dead]
/cast [mod,form:1]挑战咆哮;[form:1]低吼;[mod,form:3]斜掠;[form:3,stealth]突袭;[form:3]撕碎;台风
/cast [form:3,nostealth,nocombat]潜行;[form:3,combat] 猛虎之怒
/startattack [nostealth,combat]

E键
#showtooltip
/targetenemy [noharm][noexists][dead]
/cast [mod,form:1]挫志咆哮;[form:1]横扫(熊);[form:3,stealth]毁灭;[mod,form:3]割碎;[form:3]横扫(豹);[@cursor]自然之力
/cast [form:1]!重殴;[form:3,combat] 猛虎之怒
/startattack [nostealth,combat]

R键
#showtooltip
/use [mod,@cursor]萨隆邪铁炸弹;
/cast [nomod,form:1]激怒;[nomod,form:3]野蛮咆哮;[nomod]星辰坠落
/cast [nomod,form:3]猛虎之怒
/use [nomod,combat]10
/use [nomod,combat]13
/use [nomod,combat]14

T键
#showtooltip [mod]宁静;[form:1]狂暴回复;[form:3]畏缩;[noform:1/3]飓风
/cast 树皮术
/cast [mod]宁静;[nomod,form:1]狂暴回复;[nomod,form:3]畏缩;[nomod,noform:1/3,@cursor]飓风
/use [combat,form:1] 13
/use [combat,form:1] 14

以下宏不推荐树人使用，容易卡回人形
1键
#showtooltip
/cast [mod,@player]回春术;[form:1]裂伤(熊);[form:3]裂伤(豹);[noform:1/3,harm,exists,nodead]愤怒;[noform:1/3,@mouseover,help,exists,nodead][noform:1/3,help,exists,nodead]回春术;愤怒;
/cast [form:1]!重殴;[form:3,combat]猛虎之怒
/startattack [harm,nodead,nostealth]

2键
#showtooltip
/cast [mod,@player]愈合;[form:1]横扫(熊);[form:3]凶猛撕咬;[noform:1/3,harm,exists,nodead]星火术;[noform:1/3,@mouseover,help,exists,nodead][noform:1/3,help,exists,nodead]愈合;星火术
/cast [form:1]!重殴;[form:3,combat]猛虎之怒
/startattack [harm,nodead,nostealth]

3键
#showtooltip
/cast [mod,@player]滋养;[form:1]割伤;[form:3]割裂;[noform:1/3,harm,exists,nodead]虫群;[noform:1/3,@mouseover,help,exists,nodead][noform:1/3,help,exists,nodead]滋养;虫群
/cast [form:1]!重殴;[form:3,combat]猛虎之怒
/startattack [harm,nodead,nostealth]

4键
#showtooltip
/stopcasting [noform:1/3]
/cast [form:1/3]狂暴;[noform:1/3,@mouseover,help]自然迅捷;
/castsequence [mod,@player]治疗之触;[noform:1/3,@mouseover,help,exists,nodead][noform:1/3,help,exists,nodead]治疗之触;治疗之触

[tid=40996168]Topic[/tid] 五区-异想天开-雲極玖歌
以前分享过，不过现在用的宏之后我又修改过几次，现在重新发下保存
自用宏分享-以下宏仅个人习惯设置按键，复制粘贴请酌情自修，我没有使用自动变身宏，因为宏字数限制255变身宏-X键(ctrl+X为枭兽形态，植物人请修改为树人形态即可，或者熊猫人修改为巨熊形态)
/cast [nomod,flyable,outdoors]福星木蛟
/cast [nomod,outdoors]迅捷祖利安猛虎
/cast [mod:ctrl]!枭兽形态;[mod:shift/alt,nost

好帖留名

迅捷祖立安猛虎！